r85 - in packages: . libfile-which-perl libfile-which-perl/branches libfile-which-perl/branches/upstream libfile-which-perl/branches/upstream/current libfile-which-perl/branches/upstream/current/bin libfile-which-perl/branches/upstream/current/t libfile-which-perl/branches/upstream/current/t/test-bin libfile-which-perl/branches/upstream/current/t/test-bin/test4
Allard Hoeve
hoeve-guest@haydn.debian.org
Thu, 10 Jun 2004 07:46:10 -0600
Author: hoeve-guest
Date: 2004-06-10 07:46:07 -0600 (Thu, 10 Jun 2004)
New Revision: 85
Added:
packages/libfile-which-perl/
packages/libfile-which-perl/branches/
packages/libfile-which-perl/branches/upstream/
packages/libfile-which-perl/branches/upstream/current/
packages/libfile-which-perl/branches/upstream/current/Changes
packages/libfile-which-perl/branches/upstream/current/MANIFEST
packages/libfile-which-perl/branches/upstream/current/Makefile.PL
packages/libfile-which-perl/branches/upstream/current/README
packages/libfile-which-perl/branches/upstream/current/Which.pm
packages/libfile-which-perl/branches/upstream/current/bin/
packages/libfile-which-perl/branches/upstream/current/bin/pwhich
packages/libfile-which-perl/branches/upstream/current/t/
packages/libfile-which-perl/branches/upstream/current/t/all.t
packages/libfile-which-perl/branches/upstream/current/t/load.t
packages/libfile-which-perl/branches/upstream/current/t/simple.t
packages/libfile-which-perl/branches/upstream/current/t/test-bin/
packages/libfile-which-perl/branches/upstream/current/t/test-bin/README.txt
packages/libfile-which-perl/branches/upstream/current/t/test-bin/all
packages/libfile-which-perl/branches/upstream/current/t/test-bin/all.bat
packages/libfile-which-perl/branches/upstream/current/t/test-bin/all.exe
packages/libfile-which-perl/branches/upstream/current/t/test-bin/test1.exe
packages/libfile-which-perl/branches/upstream/current/t/test-bin/test2.bat
packages/libfile-which-perl/branches/upstream/current/t/test-bin/test3
packages/libfile-which-perl/branches/upstream/current/t/test-bin/test4/
packages/libfile-which-perl/branches/upstream/current/t/test-bin/test4/foo.txt
packages/libfile-which-perl/tags/
Log:
[svn-inject] Installing original source of libfile-which-perl
Added: packages/libfile-which-perl/branches/upstream/current/Changes
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/Changes 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/Changes 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,44 @@
+Revision history for File::Which.
+
+0.05 Mon 24 Jun 23:06:45 CET 2002
+ - Made sure the file wasn't a directory, as directories usually
+ have x set.
+ - made pwhich say so if it didn't find a file.
+ - improve file searching: file doesn't have to be -x on MacOS,
+ only -e. Same thing on DOSish, but only if the file extension is
+ in PATHEXT (so we don't look for non-executable files that
+ happen to be in PATH).
+ - For DOSish, VMS and Mac, add current directory in front of path,
+ as (on Win32) this one is searched first. (could someone tell me
+ if this assumption is true on VMS and MacOS too?)
+ - large updates to test suite: we now emulate executable files
+ inside t/test-bin/. Like this we have more control. I hope
+ this test suite will be better, but it is probably still
+ shaky. Any reports would do me a lot of good.
+
+0.04 Thu 20 Jun 21:50:30 CET 2002
+ - Re-wrote some parts for more platform-specific code (Mac and VMS
+ primarily). Thanks to Abigail and the PPT `which':
+ http://www.perl.com/language/ppt/src/which/index.html
+ - Removed the '~' handling: was probably broken anyway.
+ - fixed a bug with pwhich -a where it would return the number of
+ results instead of the results
+
+0.03 Wed 24 Apr 14:48:50 CET 2002
+ - Changed the '~' handling: last version was buggy, it needs to
+ only replace it on Unix and if $ENV{HOME} exists, replacing it
+ then with $ENV{HOME} (removes File::HomeDir dependency).
+ - Added documentation to pwhich (you can run perldoc on it now)
+
+0.02 Fri 19 Apr 02:52:15 CET 2002
+ - Some documentation changes
+ - Added where($short_exec_name) as an alias for
+ which($short_exec_name, { all => 1 }).
+ [Request from Jerrad Pierce <belg4mit (at) mit.edu>]
+ - Added the which option --all. Other options just bloat everything.
+ - Added `pwhich', perl-only replacement for `which'.
+
+0.01 Sun 14 Apr 23:05:37 CET 2002
+ - original version; extracted from DocSet. Only plain which() with
+ docs and tests.
+
Added: packages/libfile-which-perl/branches/upstream/current/MANIFEST
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/MANIFEST 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/MANIFEST 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,17 @@
+Changes
+Makefile.PL
+MANIFEST
+README
+Which.pm
+bin/pwhich
+t/load.t
+t/simple.t
+t/all.t
+t/test-bin/test1.exe
+t/test-bin/test2.bat
+t/test-bin/test3
+t/test-bin/test4/foo.txt
+t/test-bin/all
+t/test-bin/all.bat
+t/test-bin/all.exe
+t/test-bin/README.txt
\ No newline at end of file
Added: packages/libfile-which-perl/branches/upstream/current/Makefile.PL
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/Makefile.PL 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/Makefile.PL 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,13 @@
+use ExtUtils::MakeMaker;
+
+WriteMakefile(
+ 'NAME' => 'File::Which',
+ 'VERSION_FROM' => 'Which.pm', # finds $VERSION
+ 'PREREQ_PM' => {
+ 'File::Spec' => 0.60, # The version coming with perl-5.005_03
+ },
+ 'EXE_FILES' => ['bin/pwhich'],
+ ($] >= 5.005 ?
+ (ABSTRACT_FROM => 'Which.pm', # retrieve abstract from module
+ AUTHOR => 'Per Einar Ellefsen <per.einar (at) skynet.be>') : ()),
+);
Added: packages/libfile-which-perl/branches/upstream/current/README
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/README 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/README 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,56 @@
+File::Which
+===========
+
+File::Which is a portable implementation (in Perl) of `which', and can
+be used to get the absolute filename of an executable program
+installed somewhere in your PATH, or just check for its existence. It
+includes the command-line utility `pwhich' which has the same function
+as `which'.
+
+INSTALLATION
+
+To install this module type the following (on Windows, use `nmake',
+which can be obtained freely from Microsoft: see ActivePerl
+documentation):
+
+ $ tar zxvf File-Which-x.xx.tar.gz (replace x.xx with the correct version number)
+ $ cd File-Which-x.xx
+ $ perl Makefile.PL
+ $ make
+ $ make test
+ $ make install
+
+Using the CPAN shell:
+
+ $ perl -MCPAN -eshell
+ cpan> install File::Which
+ cpan> exit
+
+TESTING
+
+When you run `make test', File::Which will test some of its
+functionality. It uses the t/test-bin/ directory for this, treating
+the files below it as programs.
+
+The tests might still be a bit shaky because there is a bit of magic
+involved in doing this -- please report any problems you might have.
+
+Furthermore, the files under t/test-bin/ are *not* supposed to be
+executed: do so at your own risk. Especially, the *.exe files are not
+valid applications as they aren't compiled and might make your system
+crash or whatever. Execute them at your own risk. (But don't worry,
+this package doesn't bite otherwise :)
+
+DEPENDENCIES
+
+This module requires these other modules and libraries:
+
+ File::Spec - distributed with perl.
+
+COPYRIGHT AND LICENCE
+
+Copyright (C) 2002 Per Einar Ellefsen <per.einar (at) skynet.be>
+
+This library is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
Added: packages/libfile-which-perl/branches/upstream/current/Which.pm
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/Which.pm 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/Which.pm 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,225 @@
+package File::Which;
+
+use strict;
+
+require Exporter;
+
+@File::Which::ISA = qw(Exporter);
+
+@File::Which::EXPORT = qw(which);
+@File::Which::EXPORT_OK = qw(where);
+
+$File::Which::VERSION = '0.05';
+
+use File::Spec;
+
+my $Is_VMS = ($^O eq 'VMS');
+my $Is_MacOS = ($^O eq 'MacOS');
+my $Is_DOSish = (($^O eq 'MSWin32') or
+ ($^O eq 'dos') or
+ ($^O eq 'os2'));
+
+# For Win32 systems, stores the extensions used for
+# executable files
+# For others, the empty string is used
+# because 'perl' . '' eq 'perl' => easier
+my @path_ext = ('');
+if ($Is_DOSish) {
+ if ($ENV{PATHEXT} and $Is_DOSish) { # WinNT. PATHEXT might be set on Cygwin, but not used.
+ push @path_ext, split ';', $ENV{PATHEXT};
+ }
+ else {
+ push @path_ext, qw(.com .exe .bat); # Win9X or other: doesn't have PATHEXT, so needs hardcoded.
+ }
+}
+elsif ($Is_VMS) {
+ push @path_ext, qw(.exe .com);
+}
+
+sub which {
+ my ($exec) = @_;
+
+ return undef unless $exec;
+
+ my $all = wantarray;
+ my @results = ();
+
+ # check for aliases first
+ if ($Is_VMS) {
+ my $symbol = `SHOW SYMBOL $exec`;
+ chomp($symbol);
+ if (!$?) {
+ return $symbol unless $all;
+ push @results, $symbol;
+ }
+ }
+ if ($Is_MacOS) {
+ my @aliases = split /\,/, $ENV{Aliases};
+ foreach my $alias (@aliases) {
+ # This has not been tested!!
+ # PPT which says MPW-Perl cannot resolve `Alias $alias`,
+ # let's just hope it's fixed
+ if (lc($alias) eq lc($exec)) {
+ chomp(my $file = `Alias $alias`);
+ last unless $file; # if it failed, just go on the normal way
+ return $file unless $all;
+ push @results, $file;
+ # we can stop this loop as if it finds more aliases matching,
+ # it'll just be the same result anyway
+ last;
+ }
+ }
+ }
+
+ my @path = File::Spec->path();
+ unshift @path, File::Spec->curdir if $Is_DOSish or $Is_VMS or $Is_MacOS;
+
+ for my $base (map { File::Spec->catfile($_, $exec) } @path) {
+ for my $ext (@path_ext) {
+ my $file = $base.$ext;
+# print STDERR "$file\n";
+
+ if ((-x $file or # executable, normal case
+ ($Is_MacOS || # MacOS doesn't mark as executable so we check -e
+ ($Is_DOSish and grep { $file =~ /$_$/i } @path_ext[1..$#path_ext])
+ # DOSish systems don't pass -x on non-exe/bat/com files.
+ # so we check -e. However, we don't want to pass -e on files
+ # that aren't in PATHEXT, like README.
+ and -e _)
+ ) and !-d _)
+ { # and finally, we don't want dirs to pass (as they are -x)
+
+# print STDERR "-x: ", -x $file, " -e: ", -e _, " -d: ", -d _, "\n";
+
+ return $file unless $all;
+ push @results, $file; # Make list to return later
+ }
+ }
+ }
+
+ if($all) {
+ return @results;
+ } else {
+ return undef;
+ }
+}
+
+sub where {
+ my @res = which($_[0]); # force wantarray
+ return @res;
+}
+
+1;
+__END__
+
+=head1 NAME
+
+File::Which - Portable implementation of the `which' utility
+
+=head1 SYNOPSIS
+
+ use File::Which; # exports which()
+ use File::Which qw(which where); # exports which() and where()
+
+ my $exe_path = which('perldoc');
+
+ my @paths = where('perl');
+ - Or -
+ my @paths = which('perl'); # an array forces search for all of them
+
+=head1 DESCRIPTION
+
+C<File::Which> was created to be able to get the paths to executable programs
+on systems under which the `which' program wasn't implemented in the shell.
+
+C<File::Which> searches the directories of the user's C<PATH> (as returned by
+C<File::Spec-E<gt>path()>), looking for executable files having the name specified
+as a parameter to C<which()>. Under Win32 systems, which do not have a notion of
+directly executable files, but uses special extensions such as C<.exe> and
+C<.bat> to identify them, C<File::Which> takes extra steps to assure that you
+will find the correct file (so for example, you might be searching for C<perl>,
+it'll try C<perl.exe>, C<perl.bat>, etc.)
+
+=head1 Steps Used on Win32, DOS, OS2 and VMS
+
+=head2 Windows NT
+
+Windows NT has a special environment variable called C<PATHEXT>, which is used
+by the shell to look for executable files. Usually, it will contain a list in
+the form C<.EXE;.BAT;.COM;.JS;.VBS> etc. If C<File::Which> finds such an
+environment variable, it parses the list and uses it as the different extensions.
+
+=head2 Windows 9x and other ancient Win/DOS/OS2
+
+This set of operating systems don't have the C<PATHEXT> variable, and usually
+you will find executable files there with the extensions C<.exe>, C<.bat> and
+(less likely) C<.com>. C<File::Which> uses this hardcoded list if it's running
+under Win32 but does not find a C<PATHEXT> variable.
+
+=head2 VMS
+
+Same case as Windows 9x: uses C<.exe> and C<.com> (in that order).
+
+=head1 Functions
+
+=head2 which($short_exe_name)
+
+Exported by default.
+
+C<$short_exe_name> is the name used in the shell to call the program (for
+example, C<perl>).
+
+If it finds an executable with the name you specified, C<which()> will return
+the absolute path leading to this executable (for example, C</usr/bin/perl> or
+C<C:\Perl\Bin\perl.exe>).
+
+If it does I<not> find the executable, it returns C<undef>.
+
+If C<which()> is called in list context, it will return I<all> the
+matches.
+
+=head2 where($short_exe_name)
+
+Not exported by default.
+
+Same as C<which($short_exe_name)> in array context. Same as the
+C<`where'> utility, will return an array containing all the path names
+matching C<$short_exe_name>.
+
+
+=head1 Bugs and Caveats
+
+Not tested on VMS or MacOS, although there is platform specific code
+for those. Anyone who haves a second would be very kind to send me a
+report of how it went.
+
+File::Spec adds the current directory to the front of PATH if on
+Win32, VMS or MacOS. I have no knowledge of those so don't know if the
+current directory is searced first or not. Could someone please tell
+me?
+
+=head1 Author
+
+Per Einar Ellefsen, E<lt>per.einar (at) skynet.beE<gt>
+
+Originated in I<modperl-2.0/lib/Apache/Build.pm>. Changed for use in DocSet
+(for the mod_perl site) and Win32-awareness by me, with slight modifications
+by Stas Bekman, then extracted to create C<File::Which>.
+
+Version 0.04 had some significant platform-related changes, taken from
+the Perl Power Tools C<`which'> implementation by Abigail with
+enhancements from Peter Prymmer. See
+http://www.perl.com/language/ppt/src/which/index.html for more
+information.
+
+=head1 License
+
+This library is free software; you can redistribute it and/or modify it under
+the same terms as Perl itself.
+
+=head1 See Also
+
+L<File::Spec>, L<which(1)>, Perl Power Tools:
+http://www.perl.com/language/ppt/index.html .
+
+=cut
Added: packages/libfile-which-perl/branches/upstream/current/bin/pwhich
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/bin/pwhich 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/bin/pwhich 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,101 @@
+#!/usr/bin/perl -w
+
+use strict;
+
+use File::Which;
+use Getopt::Std;
+
+my %opts = ();
+
+getopts('av', \%opts);
+
+my @files = @ARGV;
+
+if ($opts{v}) {
+ print <<"END";
+This is pwhich running File::Which version $File::Which::VERSION
+
+Copyright 2002 Per Einar Ellefsen.
+This program is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.
+END
+
+ exit;
+}
+
+unless(@files) {
+ print <<"EOS";
+Usage: $0 [-a] [-v] programname [programname ...]
+ -a Print all matches in PATH, not just the first.
+ -v Prints version and exits
+
+EOS
+
+ exit;
+}
+
+for my $file (@files) {
+ my @result = $opts{a} ? which($file) : scalar which($file); # need to force scalar
+ @result = () unless defined $result[0]; # we might end up with @result = (undef) -> 1 elem
+ for my $result (@result) {
+ print "$result\n" if $result;
+ }
+ print STDERR "pwhich: no $file in PATH\n" unless @result;
+}
+
+__END__
+
+=head1 NAME
+
+pwhich - Perl-only `which'
+
+=head1 Synopsis
+
+ $ pwhich perl
+ $ pwhich -a perl # print all matches
+ $ pwhich perl perldoc ... # look for multiple programs
+ $ pwhich -a perl perldoc ...
+
+=head1 DESCRIPTION
+
+`pwhich' is a command-line utility program for finding paths to other
+programs based on the user's C<PATH>. It is similar to the usualy Unix
+tool `which', and tries to emulate its functionality, but is written
+purely in Perl (uses the module C<File::Which>), so is portable.
+
+
+=head1 Calling syntax
+
+ $ pwhich [-a] [-v] programname [programname ...]
+
+=head2 Options
+
+=over
+
+=item -a
+
+The option I<-a> will make C<pwhich> print all matches found in the
+C<PATH> variable instead of just the first one. Each match is printed
+on a separate line.
+
+=item -v
+
+Prints version (of C<File::Which>) and copyright notice and exits.
+
+=back
+
+=head1 License
+
+This program is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=head1 See Also
+
+L<perl>, L<File::Which>, L<which(1)>
+
+=head1 Author
+
+Per Einar Ellefsen, E<lt>per.einar (at) skynet.beE<gt>
+
+=cut
+
Added: packages/libfile-which-perl/branches/upstream/current/t/all.t
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/all.t 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/all.t 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,28 @@
+
+use Test;
+BEGIN { plan tests => 3 }
+use File::Which qw(which where);
+
+# So let's try using test-bin, huh?
+
+my $Is_VMS = ($^O eq 'VMS');
+my $Is_MacOS = ($^O eq 'MacOS');
+my $Is_DOSish = (($^O eq 'MSWin32') or
+ ($^O eq 'dos') or
+ ($^O eq 'os2'));
+my $Is_Cygwin = $^O eq 'cygwin';
+
+{
+ chdir 't' if (-d 't');
+ local $ENV{PATH} = 'test-bin';
+
+ if (not ($Is_VMS or $Is_MacOS or $Is_DOSish)) { # dunno about VMS
+ chmod 0755, "test-bin/all";
+ }
+
+ my @result = which('all');
+ ok($result[0], qr/all/i);
+ ok(@result > 0, 1);
+ ok(scalar @result, scalar where('all')); # should have as many elements.
+
+}
Added: packages/libfile-which-perl/branches/upstream/current/t/load.t
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/load.t 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/load.t 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,7 @@
+use Test;
+
+BEGIN { plan tests => 1 };
+
+use File::Which;
+
+ok(1);
Added: packages/libfile-which-perl/branches/upstream/current/t/simple.t
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/simple.t 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/simple.t 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,66 @@
+use Test;
+BEGIN { plan tests => 9; }
+use File::Which;
+use File::Spec;
+
+# check that it returns undef if no file is passed
+ok(scalar which(''), undef);
+
+ok(scalar which('non_existent_very_unlinkely_thingy_executable'), undef);
+
+# So let's try using test-bin, huh?
+
+my $Is_VMS = ($^O eq 'VMS');
+my $Is_MacOS = ($^O eq 'MacOS');
+my $Is_DOSish = (($^O eq 'MSWin32') or
+ ($^O eq 'dos') or
+ ($^O eq 'os2'));
+my $Is_Cygwin = $^O eq 'cygwin';
+
+{
+ chdir 't' if (-d 't');
+ local $ENV{PATH} = 'test-bin';
+
+ unless ($Is_VMS or $Is_MacOS or $Is_DOSish) { # dunno about VMS, think not
+ chmod 0755, "test-bin/test3";
+ }
+
+ my $skip = 0;
+ # test1.exe
+ $skip = 1 unless $Is_DOSish;
+ skip($skip, lc scalar which('test1'), 'test-bin\test1.exe', 'Looking for test1.exe');
+
+ # test2.bat
+ skip($skip, lc scalar which('test2'), 'test-bin\test2.bat', 'Looking for test2.bat');
+
+ # Make sure that test3 isn't returned by File::Which on DOSish. (it is in
+ # PATH, but is a normal file on DOSish)
+ skip($skip, scalar which('test3'), undef);
+
+ $skip = 0;
+
+ # testing Unix finally:
+ $skip = 1 if $Is_DOSish or $Is_MacOS or $Is_VMS;
+ skip($skip, scalar which('test3'), 'test-bin/test3', 'Check test3 for Unix');
+
+ $skip = 0;
+ # Cygwin: should make test1.exe transparent
+ $skip = 1 unless $Is_Cygwin;
+ skip($skip, scalar which('test1'), 'test-bin/test1', 'Looking for test1 on Cygwin: transparent to test1.exe');
+
+ ok(scalar which('test4'), undef, 'Make sure that which() doesn\'t return a directory');
+
+ chdir 'test-bin';
+
+ $skip = 0;
+
+ # Make sure that .\ stuff works on DOSish, VMS, MacOS (. is in PATH implicitly).
+ $skip = 1 unless $Is_DOSish or $Is_VMS; # or $Is_MacOS; # no idea
+ # how binaries should look
+ # like on Mac
+ skip($skip, lc scalar which('test1'),
+ File::Spec->catfile(File::Spec->curdir(), 'test1.exe'),
+ 'Looking for test1.exe in curdir'
+ );
+
+}
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/README.txt
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/test-bin/README.txt 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/test-bin/README.txt 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,5 @@
+The files included in this directory are only used for testing: they
+should not be executed: especially the *.exe files which aren't really
+compiled programs, only empty files with special filenames (as
+File::Which only cares about special attributes). Do NOT try to run
+them.
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/all
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/test-bin/all 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/test-bin/all 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,2 @@
+#!bash
+# above shebang needed so Cygwin treats it as -x
\ No newline at end of file
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/all.bat
===================================================================
Property changes on: packages/libfile-which-perl/branches/upstream/current/t/test-bin/all.bat
___________________________________________________________________
Name: svn:executable
+
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/all.exe
===================================================================
Property changes on: packages/libfile-which-perl/branches/upstream/current/t/test-bin/all.exe
___________________________________________________________________
Name: svn:executable
+
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/test1.exe
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/test-bin/test1.exe 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/test-bin/test1.exe 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,2 @@
+DO NOT RUN THIS PROGRAM
+IT IS ONLY TO TEST File::Which
Property changes on: packages/libfile-which-perl/branches/upstream/current/t/test-bin/test1.exe
___________________________________________________________________
Name: svn:executable
+
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/test2.bat
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/test-bin/test2.bat 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/test-bin/test2.bat 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,3 @@
+@echo off
+echo This is for testing File::Which
+echo Nothing interesting here!
\ No newline at end of file
Property changes on: packages/libfile-which-perl/branches/upstream/current/t/test-bin/test2.bat
___________________________________________________________________
Name: svn:executable
+
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/test3
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/test-bin/test3 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/test-bin/test3 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1,5 @@
+#!sh
+
+# ^ above shebang is needed for Cygwin
+echo "Just testing File::Which"
+echo "Nothing interesting here"
Added: packages/libfile-which-perl/branches/upstream/current/t/test-bin/test4/foo.txt
===================================================================
--- packages/libfile-which-perl/branches/upstream/current/t/test-bin/test4/foo.txt 2004-06-10 13:45:12 UTC (rev 84)
+++ packages/libfile-which-perl/branches/upstream/current/t/test-bin/test4/foo.txt 2004-06-10 13:46:07 UTC (rev 85)
@@ -0,0 +1 @@
+This file only needs to be here to test4 dir is copied over.
\ No newline at end of file