r10539 - in /branches/upstream/libxml-sax-expat-perl: ./ current/ current/Changes current/Expat.pm current/MANIFEST current/Makefile.PL current/t/ current/t/00basic.t
vdanjean at users.alioth.debian.org
vdanjean at users.alioth.debian.org
Sat Dec 1 12:36:01 UTC 2007
Author: vdanjean
Date: Sat Dec 1 12:36:01 2007
New Revision: 10539
URL: http://svn.debian.org/wsvn/?sc=1&rev=10539
Log:
[svn-inject] Installing original source of libxml-sax-expat-perl
Added:
branches/upstream/libxml-sax-expat-perl/
branches/upstream/libxml-sax-expat-perl/current/
branches/upstream/libxml-sax-expat-perl/current/Changes (with props)
branches/upstream/libxml-sax-expat-perl/current/Expat.pm (with props)
branches/upstream/libxml-sax-expat-perl/current/MANIFEST (with props)
branches/upstream/libxml-sax-expat-perl/current/Makefile.PL (with props)
branches/upstream/libxml-sax-expat-perl/current/t/
branches/upstream/libxml-sax-expat-perl/current/t/00basic.t (with props)
Added: branches/upstream/libxml-sax-expat-perl/current/Changes
URL: http://svn.debian.org/wsvn/branches/upstream/libxml-sax-expat-perl/current/Changes?rev=10539&op=file
==============================================================================
--- branches/upstream/libxml-sax-expat-perl/current/Changes (added)
+++ branches/upstream/libxml-sax-expat-perl/current/Changes Sat Dec 1 12:36:01 2007
@@ -1,0 +1,54 @@
+
+Revision history for XML::SAX::Expat:
+
+0.37 2003-07-04 22:22
+ - suppressed the warning for those strange people that process documents
+ without namespaces.
+
+0.36 2003-07-04 20:25
+ - XML::SAX::Expat went through a thorough round of testing. A number of
+ bugs were found and addressed
+ - start_document and end_document used to get the same hash, which is
+ wrong
+ - same for start_prefix_mapping and end_prefix_mapping
+ - deprecated xml_decl() in favour of adding fields to start_document()
+ - removed some useless manipulations of the element stack
+ - end_dtd() now correctly passes an empty hash instead of nothing, as
+ wouldn't start_cdata and end_cdata
+ - element_decl would return XML::Parser::ContentModel objects instead of
+ a content model string.
+ - PublicId would sometimes be undef on external_entity_decl()
+
+ - added supported_features(), as well as support for
+ http://xml.org/sax/features/external-general-entities and
+ http://xml.org/sax/features/external-parameter-entities. XML::SAX::Base
+ or XML::SAX::ParserFactory seem to have a bug in that they don't blow
+ up on unsupported features. Thanks to the numerous people on the perl-xml
+ list that supplied patches for this.
+
+0.31 - 0.35 wed 20011219 19:10:09
+ - more bugfixes (many thanks to Barrie Slaymaker for all those patches
+ and bug reports he sends me for breakfast)
+ - bugfix and docs (thanks to Dave Rolsky)
+ - bugfix (thanks to Sean M. Burke)
+
+0.20 - 0.30 mon 20011206 21:03:32
+ - a bunch of bugfixes
+
+0.05 - 0.20 mon 20011126 22:53:42
+ - added most missing callbacks
+ - made a few bits saner
+
+0.05 sat 20011118 23:01:08
+ - upgraded many bits
+ - prepared for CPAN
+ - added support for XML::SAX
+
+0.02 - 0.04 tue 20011030 20:46:42
+ - many small changes making it more SAX2 compliant, and a switch
+ to using XML::SAX::Base instead of the deprecated XML::Filter::Base
+
+0.01 mon 20011015 13:53:14
+ - original version
+ - stole Ken's original code and modified it, using techniques
+ based on the recent XML::Filter::Base
Propchange: branches/upstream/libxml-sax-expat-perl/current/Changes
------------------------------------------------------------------------------
svn:executable =
Added: branches/upstream/libxml-sax-expat-perl/current/Expat.pm
URL: http://svn.debian.org/wsvn/branches/upstream/libxml-sax-expat-perl/current/Expat.pm?rev=10539&op=file
==============================================================================
--- branches/upstream/libxml-sax-expat-perl/current/Expat.pm (added)
+++ branches/upstream/libxml-sax-expat-perl/current/Expat.pm Sat Dec 1 12:36:01 2007
@@ -1,0 +1,590 @@
+
+###
+# XML::SAX::Expat - SAX2 Driver for Expat (XML::Parser)
+# Robin Berjon <robin at knowscape.com>
+# 04/07/2003 - v.0.37
+# 15/10/2001 - v.0.01
+###
+
+package XML::SAX::Expat;
+use strict;
+use base qw(XML::SAX::Base);
+use XML::NamespaceSupport qw();
+use XML::Parser qw();
+
+use vars qw($VERSION);
+$VERSION = '0.37';
+
+
+#,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,#
+#`,`, Variations on parse `,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,#
+#```````````````````````````````````````````````````````````````````#
+
+#-------------------------------------------------------------------#
+# CharacterStream
+#-------------------------------------------------------------------#
+sub _parse_characterstream {
+ my $p = shift;
+ my $xml = shift;
+ my $opt = shift;
+
+ my $expat = $p->_create_parser($opt);
+ my $result = $expat->parse($xml);
+ $p->_cleanup;
+ return $result;
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# ByteStream
+#-------------------------------------------------------------------#
+sub _parse_bytestream {
+ my $p = shift;
+ my $xml = shift;
+ my $opt = shift;
+
+ my $expat = $p->_create_parser($opt);
+ my $result = $expat->parse($xml);
+ $p->_cleanup;
+ return $result;
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# String
+#-------------------------------------------------------------------#
+sub _parse_string {
+ my $p = shift;
+ my $xml = shift;
+ my $opt = shift;
+
+ my $expat = $p->_create_parser($opt);
+ my $result = $expat->parse($xml);
+ $p->_cleanup;
+ return $result;
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# SystemId
+#-------------------------------------------------------------------#
+sub _parse_systemid {
+ my $p = shift;
+ my $xml = shift;
+ my $opt = shift;
+
+ my $expat = $p->_create_parser($opt);
+ my $result = $expat->parsefile($xml);
+ $p->_cleanup;
+ return $result;
+}
+#-------------------------------------------------------------------#
+
+
+#-------------------------------------------------------------------#
+# $p->_create_parser(\%options)
+#-------------------------------------------------------------------#
+sub _create_parser {
+ my $self = shift;
+ my $opt = shift;
+
+ die "ParserReference: parser instance ($self) already parsing\n"
+ if $self->{_InParse};
+
+ my $featUri = 'http://xml.org/sax/features/';
+ my $ppe = ($self->get_feature($featUri . 'external-general-entities') or
+ $self->get_feature($featUri . 'external-parameter-entities') ) ? 'yes' : 'no';
+
+ my $expat = XML::Parser->new( ParseParamEnt => $ppe );
+ $expat->{__XSE} = $self;
+ $expat->setHandlers(
+ Init => \&_handle_init,
+ Final => \&_handle_final,
+ Start => \&_handle_start,
+ End => \&_handle_end,
+ Char => \&_handle_char,
+ Comment => \&_handle_comment,
+ Proc => \&_handle_proc,
+ CdataStart => \&_handle_start_cdata,
+ CdataEnd => \&_handle_end_cdata,
+ Unparsed => \&_handle_unparsed_entity,
+ Notation => \&_handle_notation_decl,
+ #ExternEnt
+ #ExternEntFin
+ Entity => \&_handle_entity_decl,
+ Element => \&_handle_element_decl,
+ Attlist => \&_handle_attr_decl,
+ Doctype => \&_handle_start_doctype,
+ DoctypeFin => \&_handle_end_doctype,
+ XMLDecl => \&_handle_xml_decl,
+ );
+
+ $self->{_InParse} = 1;
+ $self->{_NodeStack} = [];
+ $self->{_NSStack} = [];
+ $self->{_NSHelper} = XML::NamespaceSupport->new({xmlns => 1});
+ $self->{_started} = 0;
+
+ return $expat;
+}
+#-------------------------------------------------------------------#
+
+
+#-------------------------------------------------------------------#
+# $p->_cleanup
+#-------------------------------------------------------------------#
+sub _cleanup {
+ my $self = shift;
+
+ $self->{_InParse} = 0;
+ delete $self->{_NodeStack};
+}
+#-------------------------------------------------------------------#
+
+
+
+#,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,#
+#`,`, Expat Handlers ,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,#
+#```````````````````````````````````````````````````````````````````#
+
+#-------------------------------------------------------------------#
+# _handle_init
+#-------------------------------------------------------------------#
+sub _handle_init {
+ #my $self = shift()->{__XSE};
+
+ #my $document = {};
+ #push @{$self->{_NodeStack}}, $document;
+ #$self->SUPER::start_document($document);
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_final
+#-------------------------------------------------------------------#
+sub _handle_final {
+ my $self = shift()->{__XSE};
+
+ #my $document = pop @{$self->{_NodeStack}};
+ return $self->SUPER::end_document({});
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_start
+#-------------------------------------------------------------------#
+sub _handle_start {
+ my $self = shift()->{__XSE};
+ my $e_name = shift;
+ my %attr = @_;
+
+ # start_document data
+ $self->_handle_start_document({}) unless $self->{_started};
+
+ # take care of namespaces
+ my $nsh = $self->{_NSHelper};
+ $nsh->push_context;
+ my @new_ns;
+ for my $k (grep !index($_, 'xmlns'), keys %attr) {
+ $k =~ m/^xmlns(:(.*))?$/;
+ my $prefix = $2 || '';
+ $nsh->declare_prefix($prefix, $attr{$k});
+ my $ns = {
+ Prefix => $prefix,
+ NamespaceURI => $attr{$k},
+ };
+ push @new_ns, $ns;
+ $self->SUPER::start_prefix_mapping($ns);
+ }
+ push @{$self->{_NSStack}}, \@new_ns;
+
+
+ # create the attributes
+ my %saxattr;
+ map {
+ my ($ns,$prefix,$lname) = $nsh->process_attribute_name($_);
+ $saxattr{'{' . ($ns || '') . '}' . $lname} = {
+ Name => $_,
+ LocalName => $lname || '',
+ Prefix => $prefix || '',
+ Value => $attr{$_},
+ NamespaceURI => $ns || '',
+ };
+ } keys %attr;
+
+
+ # now the element
+ my ($ns,$prefix,$lname) = $nsh->process_element_name($e_name);
+ my $element = {
+ Name => $e_name,
+ LocalName => $lname || '',
+ Prefix => $prefix || '',
+ NamespaceURI => $ns || '',
+ Attributes => \%saxattr,
+ };
+
+ push @{$self->{_NodeStack}}, $element;
+ $self->SUPER::start_element($element);
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_end
+#-------------------------------------------------------------------#
+sub _handle_end {
+ my $self = shift()->{__XSE};
+
+ my %element = %{pop @{$self->{_NodeStack}}};
+ delete $element{Attributes};
+ $self->SUPER::end_element(\%element);
+
+ my $prev_ns = pop @{$self->{_NSStack}};
+ for my $ns (@$prev_ns) {
+ $self->SUPER::end_prefix_mapping( { %$ns } );
+ }
+ $self->{_NSHelper}->pop_context;
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_char
+#-------------------------------------------------------------------#
+sub _handle_char {
+ $_[0]->{__XSE}->_handle_start_document({}) unless $_[0]->{__XSE}->{_started};
+ $_[0]->{__XSE}->SUPER::characters({ Data => $_[1] });
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_comment
+#-------------------------------------------------------------------#
+sub _handle_comment {
+ $_[0]->{__XSE}->_handle_start_document({}) unless $_[0]->{__XSE}->{_started};
+ $_[0]->{__XSE}->SUPER::comment({ Data => $_[1] });
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_proc
+#-------------------------------------------------------------------#
+sub _handle_proc {
+ $_[0]->{__XSE}->_handle_start_document({}) unless $_[0]->{__XSE}->{_started};
+ $_[0]->{__XSE}->SUPER::processing_instruction({ Target => $_[1], Data => $_[2] });
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_start_cdata
+#-------------------------------------------------------------------#
+sub _handle_start_cdata {
+ $_[0]->{__XSE}->SUPER::start_cdata( {} );
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_end_cdata
+#-------------------------------------------------------------------#
+sub _handle_end_cdata {
+ $_[0]->{__XSE}->SUPER::end_cdata( {} );
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_xml_decl
+#-------------------------------------------------------------------#
+sub _handle_xml_decl {
+ my $self = shift()->{__XSE};
+ my $version = shift;
+ my $encoding = shift;
+ my $standalone = shift;
+
+ if (not defined $standalone) { $standalone = ''; }
+ elsif ($standalone) { $standalone = 'yes'; }
+ else { $standalone = 'no'; }
+ my $xd = {
+ Version => $version,
+ Encoding => $encoding,
+ Standalone => $standalone,
+ };
+ #$self->SUPER::xml_decl($xd);
+ $self->_handle_start_document($xd);
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_notation_decl
+#-------------------------------------------------------------------#
+sub _handle_notation_decl {
+ my $self = shift()->{__XSE};
+ my $notation = shift;
+ shift;
+ my $system = shift;
+ my $public = shift;
+
+ my $not = {
+ Name => $notation,
+ PublicId => $public,
+ SystemId => $system,
+ };
+ $self->SUPER::notation_decl($not);
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_unparsed_entity
+#-------------------------------------------------------------------#
+sub _handle_unparsed_entity {
+ my $self = shift()->{__XSE};
+ my $name = shift;
+ my $system = shift;
+ my $public = shift;
+ my $notation = shift;
+
+ my $ue = {
+ Name => $name,
+ PublicId => $public,
+ SystemId => $system,
+ Notation => $notation,
+ };
+ $self->SUPER::unparsed_entity_decl($ue);
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_element_decl
+#-------------------------------------------------------------------#
+sub _handle_element_decl {
+ $_[0]->{__XSE}->SUPER::element_decl({ Name => $_[1], Model => "$_[2]" });
+}
+#-------------------------------------------------------------------#
+
+
+#-------------------------------------------------------------------#
+# _handle_attr_decl
+#-------------------------------------------------------------------#
+sub _handle_attr_decl {
+ my $self = shift()->{__XSE};
+ my $ename = shift;
+ my $aname = shift;
+ my $type = shift;
+ my $default = shift;
+ my $fixed = shift;
+
+ my ($vd, $value);
+ if ($fixed) {
+ $vd = '#FIXED';
+ $default =~ s/^(?:"|')//; #"
+ $default =~ s/(?:"|')$//; #"
+ $value = $default;
+ }
+ else {
+ if ($default =~ m/^#/) {
+ $vd = $default;
+ $value = '';
+ }
+ else {
+ $vd = ''; # maybe there's a default ?
+ $default =~ s/^(?:"|')//; #"
+ $default =~ s/(?:"|')$//; #"
+ $value = $default;
+ }
+ }
+
+ my $at = {
+ eName => $ename,
+ aName => $aname,
+ Type => $type,
+ ValueDefault => $vd,
+ Value => $value,
+ };
+ $self->SUPER::attribute_decl($at);
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_entity_decl
+#-------------------------------------------------------------------#
+sub _handle_entity_decl {
+ my $self = shift()->{__XSE};
+ my $name = shift;
+ my $val = shift;
+ my $sys = shift;
+ my $pub = shift;
+ my $ndata = shift;
+ my $isprm = shift;
+
+ # deal with param ents
+ if ($isprm) {
+ $name = '%' . $name;
+ }
+
+ # int vs ext
+ if ($val) {
+ my $ent = {
+ Name => $name,
+ Value => $val,
+ };
+ $self->SUPER::internal_entity_decl($ent);
+ }
+ else {
+ my $ent = {
+ Name => $name,
+ PublicId => $pub || '',
+ SystemId => $sys,
+ };
+ $self->SUPER::external_entity_decl($ent);
+ }
+}
+#-------------------------------------------------------------------#
+
+
+#-------------------------------------------------------------------#
+# _handle_start_doctype
+#-------------------------------------------------------------------#
+sub _handle_start_doctype {
+ my $self = shift()->{__XSE};
+ my $name = shift;
+ my $sys = shift;
+ my $pub = shift;
+
+ $self->_handle_start_document({}) unless $self->{_started};
+
+ my $dtd = {
+ Name => $name,
+ SystemId => $sys,
+ PublicId => $pub,
+ };
+ $self->SUPER::start_dtd($dtd);
+}
+#-------------------------------------------------------------------#
+
+#-------------------------------------------------------------------#
+# _handle_end_doctype
+#-------------------------------------------------------------------#
+sub _handle_end_doctype {
+ $_[0]->{__XSE}->SUPER::end_dtd( {} );
+}
+#-------------------------------------------------------------------#
+
+
+#-------------------------------------------------------------------#
+# _handle_start_document
+#-------------------------------------------------------------------#
+sub _handle_start_document {
+ $_[0]->SUPER::start_document($_[1]);
+ $_[0]->{_started} = 1;
+}
+#-------------------------------------------------------------------#
+
+
+#-------------------------------------------------------------------#
+# supported_features
+#-------------------------------------------------------------------#
+sub supported_features {
+ return (
+ $_[0]->SUPER::supported_features,
+ 'http://xml.org/sax/features/external-general-entities',
+ 'http://xml.org/sax/features/external-parameter-entities',
+ );
+}
+#-------------------------------------------------------------------#
+
+
+
+
+
+#,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,#
+#`,`, Private Helpers `,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,#
+#```````````````````````````````````````````````````````````````````#
+
+#-------------------------------------------------------------------#
+# _create_node
+#-------------------------------------------------------------------#
+#sub _create_node {
+# shift;
+# # this may check for a factory later
+# return {@_};
+#}
+#-------------------------------------------------------------------#
+
+
+1;
+#,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,#
+#`,`, Documentation `,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,`,#
+#```````````````````````````````````````````````````````````````````#
+
+=pod
+
+=head1 NAME
+
+XML::SAX::Expat - SAX2 Driver for Expat (XML::Parser)
+
+=head1 SYNOPSIS
+
+ use XML::SAX::Expat;
+ use XML::SAX::MyFooHandler;
+ my $h = XML::SAX::MyFooHandler->new;
+ my $p = XML::SAX::Expat->new(Handler => $h);
+ $p->parse_file('/path/to/foo.xml');
+
+=head1 DESCRIPTION
+
+This is an implementation of a SAX2 driver sitting on top of Expat
+(XML::Parser) which Ken MacLeod posted to perl-xml and which I have
+updated.
+
+It is still incomplete, though most of the basic SAX2 events should be
+available. The SAX2 spec is currently available from
+http://cvs.sourceforge.net/cgi-bin/viewcvs.cgi/~checkout~/perl-xml/libxml-perl/doc/sax-2.0.html?rev=HEAD&content-type=text/html
+
+A more friendly URL as well as a PODification of the spec are in the
+works.
+
+=head1 METHODS
+
+The methods defined in this class correspond to those listed in the
+PerlSAX2 specification, available above.
+
+
+=head1 MISSING PARTS
+
+XML::Parser has no listed callbacks for the following events, which
+are therefore not presently generated (ways may be found in the
+future):
+
+ * ignorable_whitespace
+ * skipped_entity
+ * start_entity / end_entity
+ * resolve_entity
+
+Ways of signalling them are welcome. In addition to those,
+set_document_locator is not yet called.
+
+=head1 CAVEATS
+
+ - this module supports the features http://xml.org/sax/features/external-general-entities
+ and http://xml.org/sax/features/external-parameter-entities but turning one on also turns
+ the other on (this maps to the XML::Parser ParseParamEnts option). This may be fixed in
+ the future, so don't rely on this behaviour.
+
+=head1 TODO
+
+ - reuse Ken's tests and add more
+
+=head1 AUTHOR
+
+Robin Berjon, robin at knowscape.com; stolen from Ken Macleod,
+ken at bitsko.slc.ut.us, and with suggestions and feedback from
+perl-xml.
+
+=head1 COPYRIGHT
+
+Copyright (c) 2001, 2002 Robin Berjon. All rights reserved. This program is
+free software; you can redistribute it and/or modify it under the same
+terms as Perl itself.
+
+=head1 SEE ALSO
+
+XML::Parser::PerlSAX
+
+=cut
Propchange: branches/upstream/libxml-sax-expat-perl/current/Expat.pm
------------------------------------------------------------------------------
svn:executable =
Added: branches/upstream/libxml-sax-expat-perl/current/MANIFEST
URL: http://svn.debian.org/wsvn/branches/upstream/libxml-sax-expat-perl/current/MANIFEST?rev=10539&op=file
==============================================================================
--- branches/upstream/libxml-sax-expat-perl/current/MANIFEST (added)
+++ branches/upstream/libxml-sax-expat-perl/current/MANIFEST Sat Dec 1 12:36:01 2007
@@ -1,0 +1,5 @@
+Changes
+Expat.pm
+Makefile.PL
+MANIFEST
+t/00basic.t
Propchange: branches/upstream/libxml-sax-expat-perl/current/MANIFEST
------------------------------------------------------------------------------
svn:executable =
Added: branches/upstream/libxml-sax-expat-perl/current/Makefile.PL
URL: http://svn.debian.org/wsvn/branches/upstream/libxml-sax-expat-perl/current/Makefile.PL?rev=10539&op=file
==============================================================================
--- branches/upstream/libxml-sax-expat-perl/current/Makefile.PL (added)
+++ branches/upstream/libxml-sax-expat-perl/current/Makefile.PL Sat Dec 1 12:36:01 2007
@@ -1,0 +1,31 @@
+use ExtUtils::MakeMaker;
+# See lib/ExtUtils/MakeMaker.pm for details of how to influence
+# the contents of the Makefile that is written.
+WriteMakefile(
+ NAME => 'XML::SAX::Expat',
+ VERSION_FROM => 'Expat.pm',
+ AUTHOR => 'Robin Berjon',
+ ABSTRACT => 'SAX Driver for Expat',
+ PREREQ_PM => {
+ XML::SAX::Base => '1.00',
+ XML::Parser => '2.27',
+ XML::NamespaceSupport => '0.03',
+ XML::SAX => '0.03',
+ },
+);
+
+
+## add ourselves to the list of installed parsers
+sub MY::install {
+ package MY;
+ my $script = shift->SUPER::install(@_);
+ $script =~ s/install :: (.*)$/install :: $1 install_sax_expat/m;
+ $script .= <<"INSTALL";
+
+install_sax_expat :
+\t\@\$(PERL) -MXML::SAX -e "XML::SAX->add_parser(q(XML::SAX::Expat))->save_parsers()"
+
+INSTALL
+
+ return $script;
+}
Propchange: branches/upstream/libxml-sax-expat-perl/current/Makefile.PL
------------------------------------------------------------------------------
svn:executable =
Added: branches/upstream/libxml-sax-expat-perl/current/t/00basic.t
URL: http://svn.debian.org/wsvn/branches/upstream/libxml-sax-expat-perl/current/t/00basic.t?rev=10539&op=file
==============================================================================
--- branches/upstream/libxml-sax-expat-perl/current/t/00basic.t (added)
+++ branches/upstream/libxml-sax-expat-perl/current/t/00basic.t Sat Dec 1 12:36:01 2007
@@ -1,0 +1,7 @@
+BEGIN { $| = 1; print "1..1\n"; }
+END {print "not ok 1\n" unless $loaded;}
+use XML::SAX::Expat;
+$loaded = 1;
+print "ok 1\n";
+
+# these tests are temporary...
Propchange: branches/upstream/libxml-sax-expat-perl/current/t/00basic.t
------------------------------------------------------------------------------
svn:executable =
More information about the Pkg-perl-cvs-commits
mailing list